Perl (99) - Curses - měření rychlosti psaní

Perl Znalosti nabyté v předchozích dvou dílech nyní použijeme k napsání programu, který bude testovat rychlost psaní.

29.1.2010 06:00 | Jiří Václavík | přečteno 9097×

Aplikace, která je cílem dnešního dílu, bude obsahovat několik textů a uživatel se bude snažit náhodně vybraný text opsat v co nejkratším čase.

Program bude fungovat tak, že budeme mít na úvod na obrazovce nějaký text. Po každém uživatelem správně opsaném znaku z tohoto textu se kurzor posune na následující pozici. Tak tomu bude až do té doby, než uživatel opíše celý text. Jeho čas budeme stopovat a na závěr vypíšeme statistiku počtu úhozů za sekundu. Pokud uživatel udělá chybu (stiskne jinou klávesu, než by měl), nebude na ni program reagovat.

Poznámka - Lepším řešením místo ignorování špatně opsaných znaků by z hlediska uživatele možná bylo počítání chyb. Avšak to bychom museli nějak definovat počet chyb, nebo-li metriku, která dvěma textům přiřadí jejich vzdálenost. Příkladem vhodné metriky pro takovýto účel je Levenshteinova metrika. Mohli bychom tedy použít například modul Text::LevenshteinXS.

A abychom vyzkoušeli vše, co jsme se naučili, tak na úvod programu navíc vytiskneme doprostřed obrazovky uvítací okno.

Realizace

Abychom mohli napsat tento program, musíme nějak vyřešit problém, jak stopovat čas. Nejsnažším řešením bude použití modulu - například Time::Stopwatch, který je k dispozici na CPANu.

use Time::Stopwatch;

Dále třeba definovat několik textů, z nichž bude později jeden vybrán.

my @texty = ("text 1", "dlouhy text, dlouhy text, dlouhy text, dlouhy text, dlouhy text, dlouhy text, dlouhy text, dlouhy text, dlouhy text, dlouhy text, dlouhy text, dlouhy text, dlouhy text, dlouhy text, dlouhy text, dlouhy text, dlouhy text", "a jeste jeden text");

Začátek programu bude stejný jako vždy. Po volání initscr ještě zneviditelníme kurzor a zavoláme noecho. Výstup si budeme řídit sami.

initscr;
END{endwin;}
curs_set(0);
noecho;

Prvním úkolem bylo vytvořit uvítací okno uprostřed obrazovky. K tomu budeme potřebovat pozice horního levého rohu. Musíme tedy získat rozměry obrazovky.

getmaxyx(stdscr, $y, $x);

A také je třeba určit rozměry okna. Protože zde uvedeme jméno programu a verzi zvolíme výšku 7 řádků.

my $vyska_okna=7;
my $sirka_okna=30;

Dále již můžeme okno vytvořit

refresh;
my $w = newwin($vyska_okna, $sirka_okna, ($y-$vyska_okna)/2, ($x-$sirka_okna)/2);
box($w, 0, 0);

Nyní doprostřed druhého a čtvrtého řádku v okně vložíme text.

getmaxyx($w, $w_y, $w_x);
addstr($w, 2, ($w_x - length($intro))/2, $intro);
addstr($w, 4, ($w_x - length($verze))/2, $verze);
refresh($w);

Úvodní okno je hotové. Počkáme tedy na stisk klávesy. Nastavíme timeout tak, že pokud by do dvou sekund nepřišel, budeme pokračovat dále.

timeout(2000);
getch;
notimeout(stdscr, 1);
delwin($w);

Protože se ale zrušením okna na obrazovce nic nesmaže, bude třeba ho odstranit. Momentálně nemáme zobrazeno nic jiného než toto okno, tedy můžeme použít funkci clear.

clear;

Nyní zobrazíme náhodně vylosovaný text a výzvu k zadání klávesy ENTER. Jakmile se tak stane, začneme stopovat čas. Výzvu zobrazíme na úvodní řádek a text začneme zobrazovat až na řádek čtvrtý.

addstr("Stisknete ENTER pro pokracovani");

Nyní vylosujeme text. Pro jistotu z něj odstraníme znaky nového řádku, aby nám nedělělaly neplechu.

$text = $texty[int(rand($#texty+1))];
$text =~ tr/\n/ /;

A teď nastane problém, pokud máme text delší než jeden řádek. Protože chceme, aby uživatel opisoval vždy řádek pod vzorovým textem, budeme muset tisknout řádek po částech tak, aby mezi nimi byly dvouřádkové mezery.

Řádek tedy budeme postupně rozdělovat pomocí substr a v cyklu tisknout. Vždy před tiskem se budeme muset posunout funkcí move o tři řádky dolů. Nastavíme proměnnou $prvni_radek na 3 a od tohoto řádku začneme postupně vypisovat text.

for(my($radek,$pozice)=($prvni_radek,0); $pozice<length($text); $pozice+=$x, $radek+=3){
    move($radek, 0);
    addstr(substr($text, $pozice, $x));
}

Jakmile dostaneme od uživatele znak nového řádku, můžeme pokračovat.

while(($key=getch()) ne "\n"){}

Musíme udělat několik věcí:

Smazání provedeme tak, že text přepíšeme mezerami. Potřebujeme tedy znát délku textu. Budeme muset přepsat výzvu, abychom ji mohli určit.

my $s = "Stisknete ENTER pro start";
addstr($s);

Dále napíšeme funkci delete_string, která bude mazat daný počet znaků od určité pozice. Protože by funkce neměla zasahovat do okolí, přesuneme v jejím závěru kurzor opět na původní souřadnice.

sub delete_string {
    my($y, $x, $kolik) = @_;
    my($puv_x, $puv_y);
    getyx($puv_y, $puv_x);
    move($y, $x);
    addstr(" " x $kolik);
    move($puv_y, $puv_x);
}

Pro smazání výzvy tedy použijeme tento příkaz.

delete_string(0, 0, length($s));

Druhým úkolem bylo nastavit kurzor na příslušnou pozici.

move($pozice_y, $pozice_x);
curs_set(1);

Odteď začneme měřit čas. Time::Stopwatch využívá mechanizmus tie, takže stačí navázat proměnnou $timer a při jejím čtení získáme vždy uplynulý čas.

tie my $timer, "Time::Stopwatch";

V cyklu budeme načítat znak po znaku text od uživatele.

while($key = getch){
    #...
}

Pokud dostaneme správný znak, posuneme se na pozici následující. Abychom mohli správnost znaku testovat, musíme pomocí substr tento znak vyseparovat ze zadání textu. Také budeme muset udržovat proměnnou uchovávající pozici v textu.

Napíše-li uživatel správný znak, musíme nastavit $pozice_y a $pozice_x na nové hodnoty a přesunout na tuto pozici kurzor.

    if($key eq substr($text, $pozice_v_textu, 1)){
        addstr($key);
        $pozice_v_textu++;
        $pozice_y = $prvni_radek+1+3*int($pozice_v_textu/$x);
        $pozice_x = $pozice_v_textu % $x;
        move($pozice_y, $pozice_x);
    }

Pokud se uživatel splete, znak vymažeme a vrátíme kurzor.

    else{
        move($pozice_y, $pozice_x);
        addstr(" ");
        move($pozice_y, $pozice_x);
    }

To, zda již byl opsán celý text, poznáme podle stavu proměnné $pozice_v_textu. Shoduje-li se její obsah s délkou řetězce, pak bylo dosaženo cíle. Můžeme tedy směle tisknout statistiku.

    if(length($text) == $pozice_v_textu){
        move(0, 0);
        addstr("HOTOVO!");
        move(1, 0);
        addstr(sprintf("Pocet znaku: %4d   Vas cas: %5.2fs   Znaku/s: %5.2f",
            length($text), $timer, length($text)/$timer));
        last;
    }

Na závěr počkáme na ENTER a program ukončíme.

while(getch() ne "\n"){;}

Výsledek

Jak vypadá náš program po spuštění, zachycují následující obrázky. Zdrojový kód je možné stáhnout.

Po spuštění *** Před stopováním

V průběhu psaní *** Výpis výsledků

Online verze článku: http://www.linuxsoft.cz/article.php?id_article=1671