Perl (75) - Obsluha více klientů

Perl Ukážeme si dvě metody, které vylepšují server z minulého dílu tak, aby obsluhoval více klientů zároveň.

13.1.2009 06:00 | Jiří Václavík | přečteno 11760×

Náš jednoduchý klient-server mechanizmus z minulého dílu uměl najednou obsluhovat jediného klienta. To však v praxi většinou nestačí. Dnes se budeme zabývat právě servery, které jsou schopny odpovídat na požadavky většího množství klientů zároveň.

Představíme si následující dva způsoby, jak lze obsluhovat více klientů.

Rozvětvení serveru

První možností jak reagovat na požadavky více klientů je použití forku. fork dokáže větvit proces, což přesně potřebujeme.

Jak již bylo řečeno, správný server se neptá, ale pouze naslouchá požadavkům klientů a odpovídá, je-li tázán. Naprogramujeme si tedy nějaký server, který bude této koncepci odpovídat.

Jako ukázku si napíšeme server, kterému budou klienti posílat nějaké řetězce. Ty server zpracuje a klientům pošle řetězce, v nichž bude přehozené pořadí písmen. Obsluhovaných klientů bude moci být několik zároveň a všechny požadavky budou neprodleně vyřizovány.

Začátek skriptu serveru bude stejný jako u serveru z minulého dílu.

use IO::Socket;

my $port = 7779;
my $ip = "192.168.0.10";
my $pid;

my $server = IO::Socket::INET->new(
    Proto     => "tcp",
    LocalPort => $port,
    LocalAddr => $ip,
    Listen    => 1,
    Reuse     => 1
) or die "Chyba pri vytvareni serveru! $!";

Zajímavé to začíná být od naslouchání. Po každém připojení klienta ho vždy odštěpíme jako zvláštní proces pomocí forku. Tím si zajistíme, že původní proces se může bez vyrušování stále soustředit na naslouchání novým klientům, zatímco odštěpený synovský proces může obsluhovat příslušného klienta.

while(my $klient = $server->accept()){
    #odštěpíme proces, který sám klienta obslouží a vrátíme se zpět k naslouchání
    next unless $pid = fork;

    #zde bude probíhat komunikace s odštěpeným klientem

    exit; #komunikace skončila - odštěpený proces ukončíme
}

Je-li ukončen synovský proces, obdržíme signál CHLD. Příkazem wait odstraníme případné zombie procesy.

$SIG{"CHLD"} = sub {wait();};

Dále je už vše takové, tak to známe z minulého dílu. Zbývá už jen samotná komunikace s klientem. Přijmeme tedy data, převrátíme v nich znaky a odešleme zpět klientovi. Navíc vytiskneme pro informaci hlášku, která říká co a komu se posílá.

    while (my $prichozi = <$klient>){
        chomp $prichozi;
        print "Prijat retezec $prichozi od klienta ($pid)\n";
        my $odchozi = reverse $prichozi;
        print "Posilam retezec $odchozi klientovi ($pid)\n";
        print $klient "$odchozi\n";
    }

Tento přístup nám v zásadě neříká nic nového. Pouze jsme aplikovali znalosti z minulých dílů a dali je dohromady.

Přepínání mezi klienty

Nyní si vyzkoušíme jiný přístup k obsluze více klientů. Tentokrát nebudeme spouštět více instancí programu, ale postačí nám jediné vlákno. Mezi klienty budeme přepínat. Na to už ale musíme použít něco nového.

Modul IO::Select nám umožňuje zjistit, kteří z klientů jsou aktuálně schopni poslat požadavek. Jakmile takový klient existuje, obsloužíme ho, okamžitě se vrátíme a opět zjišťujeme, zda se chce nějaký klient ptát. Důležité je, že klienta obsluhujeme až je-li připraven odesílat data. Máme tak zaručeno, že nebudeme čekat, protože pokud se dostaneme až sem, klient data již odesílá a čeká pouze na to, až je server přijme.

Nejdříve opět vytvoříme socket, a pomocí něj dále definujeme instanci objektu IO::Select.

use IO::Select;
use IO::Socket;
use strict;

my @read;
my $sock = new IO::Socket::INET(
    LocalPort => 7778,
    Listen    => 1,
    Reuse     => 1
);
my $select = new IO::Select($sock);

Dále budeme v cyklu čekat na klenty, z nichž lze číst. Zjistíme je metodou can_read z modulu IO::Select. Tyto klienty si uchováme a v cyklu s každým z nich provedeme nějakou operaci.

while(@read = $select->can_read) {
    foreach my $fh (@read) {
        #zde zpracujeme zpravu od klienta
    }
}

Při prvním průchodu vytvoříme nový klientský socket a při dalších už zpracováváme jeho požadavky. Pokud klient ukončil spojení, uděláme totéž.

        #vytvoříme socket a přidáme do selectu
        if($fh == $sock) {
            my $new = $sock->accept;
            $select->add($new);

        #můžeme číst data z klienta - hned tedy vyřídíme jeho požadavek
        }else{
            my $zprava;
            chomp($zprava = <$fh>);
            if($zprava){
                $zprava = reverse $zprava;
                print $fh "$zprava\n";
            }else{
                $select->remove($fh);
                $fh->close;
            }
        }

Princip tohoto serveru spočívá v tom, že jakmile obdrží od některého klienta zprávu, zpracuje ji a dále na tohoto klienta nečeká. Server jím tak není blokován a okamžitě po vyřízení požadavku je k dispozici ostatním.

Online verze článku: http://www.linuxsoft.cz/article.php?id_article=1573