Perl (40) - Dodatky k modulům

40. díl téměř dokončuje kapitolu o modulech. Hlavními tématy jsou určení cest k adresářům s moduly, speciální procedura AUTOLOAD a něco více k zavádění modulů. Z modulů nám tak zbyde už jen archiv CPAN, který si zaslouží vlastní díl.

17.8.2006 06:00 | Jiří Václavík | přečteno 13601×

Cesty k modulům

Použijeme-li ve svém skriptu příkaz use Modul;, Perl implicitně tento modul hledá v adresářích, které jsou uvedené v poli @INC. Obsahem @INC jsou totiž uložené cesty k modulům.

@INC je už přednastavené, ale mnohdy je třeba ho ještě ručně upravit. Typicky to nastane tehdy, pokud máme někde vlastní úložiště modulů. Je několik způsobů, jak obsah pole @INC ovlivnit.

Prvním z nich je pragma lib, pomocí níž s polem @INC můžeme manipulovat. Podívejme se na tento úsek kódu, který demostruje použití lib.

$, = "\n";
use lib qw(/home/instal/perl/lib);
print @INC;

Na první místo pole @INC byla přidána cesta /home/instal/perl/lib. Pokusíme-li se nyní načíst nějaký modul, prvním místem, kde ho bude Perl hledat bude právě /home/instal/perl/lib.

A navíc, pokud existuje adresář /home/instal/perl/lib/architektura/auto, bude přidán i ten. Bude mít dokonce ještě větší prioritu, protože moduly psané na míru pro konkrétní architekturu mají pochopitelně přednost před moduly obecnými. Názvem architektury je architektura vašeho stroje, tedy například i586-linux.

Poznámka: Poměrně častým problémem při editaci @INC je přidávání adresáře, ve kterém je program. Nelze napsat pouze use lib '.';, protože když pak tento program spouštíme z jiného adresáře, '.' reprezentuje právě jej a nikoliv adresář, ve kterém je umístěn program. Nelze tedy zadat napevno '.'. Problém však vyřešíme odseparováním cesty z proměnné $0 a importem v bloku BEGIN.

BEGIN {
    require lib;
    my($dir) = $0 =~ /(.*)\//;
    lib->import($dir);
}

Použitím klíčového slova no namísto use naopak adresář z @INC odstraníme.

Ještě předtím, než je pole @INC změněno, je vytvořena jeho kopie @lib::ORIG_INC. Vždy tak můžeme získat původní @INC.

Poznámka: Možná vás napadlo, že by cestu do pole @INC mělo jít přidat i obyčejným přidáním prvku na začátek tohoto pole. Proč to děláme tak složitě?

unshift(@INC, "/nova/cesta/k/modulum");

Tak jednoduché to bohužel není. Jak bude vysvětleno dále v tomto díle, import pomocí use se provádí už při kompilaci. Protože ale přiřazujeme cestu až za běhu, modul nalezen nebude. Řešením by teoreticky bylo použití příkazu require nebo uzavření příkazu unshift do bloku BEGIN. Ale proč to dělat, když zde máme pragmu lib...

Jsou i jiné možnosti, jak dostat do @INC další adresář. Například volba -I při spouštění programu. Přepínač -I přijímá seznam, takže jej lze uvést i vícekrát.

$ perl -I/home/instal/perl/lib -I/media/sources/perl5.8.8/libs prog.pl

Cesty k modulům lze také uchovávat v proměnné prostředí PERL5LIB, případně PERLLIB. To je výhodné zejména tehdy, pokud potřebujeme nějakou cestu přidat dlouhodobě. Stačí jen umístit do konfiguračního souboru shellu řádek podobný následujícímu.

export PERL5LIB=/nova/cesta/k/modulum

Speciální bloky

Perl rozpoznává takzvaný globální konstruktor modulu (blok BEGIN) a globální destruktor modulu (blok END). V podstatě to jsou zvláštní podprogramy s rezervovanými názvy. Lze je užít v libovolném perlovém programu.

BEGIN

Ne náhodou se bloku BEGIN říká konstruktor. Příkazy uvnitř něj jsou totiž určené k inicializaci. Kód, zapsaný uvnitř BEGIN se provede v okamžiku překladu. Typické je to pro import modulů.

Snadno se o tom můžeme přesvědčit pokusem. Dále v tomto článku poznáme další funkci na zavedení souboru - funkci require. Ta importuje soubor až za běhu programu (tedy v době, kdy už je po překladu). Vytvořme si dva programy. V prvním z nich budeme funkci require volat v bloku BEGIN a v druhém mimo něj. Dále přeložme tyto dva programy pomocí příkazu perlcc (ten převede program pouze do binární spustitelné podoby - tedy přibližně to, co udělá gcc z programu v C). Teď jsou ve stavu, kdy skončil překlad, ale ještě nezačal běh. Znamená to, že soubor s require v bloku BEGIN by měl obsahovat vkládaný soubor a tudíž by měl být větší.

END

Obsah bloku END se vykoná bezprostředně před ukončením běhu programu. Přitom vůbec nezáleží, zda byl program úspěšný. Tedy i v případě volání funkce die. Opět je zde název destruktor na místě.

print "Vystup programu\n";
BEGIN { print "V bloku BEGIN\n" }
END { print "V bloku END\n" }

Zajímavé je, že bloků jména BEGIN či END může být více v jediném souboru. Potom záleží na jejich pořadí. Bloky BEGIN jsou vykonávány od začátku souboru ke konci, bloky END naopak.

END   { print "V bloku END 1\n" }
BEGIN { print "V bloku BEGIN 1\n" }
END   { print "V bloku END 2\n" }
BEGIN { print "V bloku BEGIN 2\n" }
END   { print "V bloku END 3\n" }
BEGIN { print "V bloku BEGIN 3\n" }
BEGIN { print "V bloku BEGIN 4\n" }
END   { print "V bloku END 4\n" }

Poslední zmíněné pravidlo je patrné z výstupu tohoto kódu.

$ perl bloky.pl
V bloku BEGIN 1
V bloku BEGIN 2
V bloku BEGIN 3
V bloku BEGIN 4
V bloku END 4
V bloku END 3
V bloku END 2
V bloku END 1
$

Existují ještě další 2 speciální bloky s podobným významem. Jsou to CHECK a INIT. Tyto bloky slouží k zachycení fáze mezi překladem a během programu. Pořadí vykonávání jednotlivých částí programu je následující:

  1. blok BEGIN
  2. blok CHECK
  3. blok INIT
  4. hlavní program
  5. blok END
Názorný příklad na všechny 4 bloky je v manuálové stránce perlmod(1).

Zavedení modulu

Existují všeho všudy 2 příkazy na zavedení externího souboru do programu. Jsou to use a require.

Mnohé nám o nich napoví to, jaký k sobě mají vzájemně vztah. Zde jsou 3 způsoby, jakými můžeme use použít.

  use Modul;
  use Modul (seznam);
  use Modul ();

Tyto zápisy lze přepsat tak, že nahradíme use za require. Předchozím ekvivalentní zápisy pak vypadají takto.

  BEGIN { require Modul; import Modul; }
  BEGIN { require Modul; import Modul (seznam); }
  BEGIN { require Modul; }

Jak je ze zmíněných analogických příkazů patrné, require jsme umístili do bloku BEGIN, aby se vykonával už při překladu. Z toho nám krásně vyplynul hlavní rozdíl mezi use a require. Příkaz use zavádí modul už v době překladu. Oproti tomu require soubory importuje za běhu programu.

Je-li parametrem zaváděcích příkazů slovo bez uvozovek, hledá se stejnojmenný soubor s příponou .pm, ve kterém jsou nahrazeny znaky :: za lomítko. Řetězec Math::BigFloat je podle tohoto pravidla převeden na soubor Math/BigFloat.pm. Ten je hledán v adresářích uvedených v poli @INC. Další možností je uvést parametr do uvozovek. Pak se v adresářích @INC hledá soubor, jehož název přesně bez úprav odpovídá tomuto řetězci.

Parametrem příkazů use nebo require může být i číslo verze interpretu Perlu. Program je pak spuštěn jen v případě, že požadovaná verze je starší nebo stejná než aktuální verze interpretu. Jinak se zobrazí chybová zpráva.

  Perl v6.0.0 required--this is only v5.8.6, stopped at require.pl line 1.

Procedura AUTOLOAD

Pokud definujeme podprogram s názvem AUTOLOAD, spustí se tehdy, pokud voláme nedefinovanou proceduru. Název volané neexistující procedury je uvnitř podprogramu AUTOLOAD dostupný v proměnné $AUTOLOAD. Argumenty volané procedury jsou pomocí @_, tedy opět jako argumenty, předány do AUTOLOAD.

sub AUTOLOAD {
    my(@argumenty) = @_; #obsahy prvků pole @_ jsou "a", "bc", 96
    print "Procedura $AUTOLOAD neexistuje!\n";
}

blabla("a", "bc", 96);

Protože jsme žádný podprogram blabla nedefinovali, spustí se AUTOLOAD a výsledkem bude hláška Procedura main::blabla neexistuje!.

Pro zajímavost uveďme bez dalšího komentáře použití AUTOLOAD s funkcí system. Ta nebyla dosud v seriálu popsána, ale její funkci lze z programu intuitivně vytušit.

sub AUTOLOAD {
    $AUTOLOAD =~ s/.*:://;
    system($AUTOLOAD, @_);
}

pwd();
ls("-l", "/home");
top();

Příště se podíváme na archiv CPAN.

Online verze článku: http://www.linuxsoft.cz/article.php?id_article=1298