Perl (38) - Rozhraní modulu

Rozhraní modulu se obvykle definuje pomocí modulu Exporter. Určujeme tak, která data mají být veřejná a která soukromá.

18.7.2006 06:00 | Jiří Václavík | přečteno 14224×

Rozhraní modulu jsou proměnné a podprogramy, které modul poskytuje okolí. K jeho definici se běžně užívá speciální modul Exporter. Ten určuje několik proměnných se zvláštní funkcí, které budou definované uvnitř našeho modulu. Tyto proměnné mají řídící funkci a vytvářejí rozhraní, které bude modul poskytovat. Postupně si tyto proměnné představíme blíže.

Pole @EXPORT

Do tohoto pole přiřazujeme proměnné, které mají být dostupné nejen v balíku modulu (např. Mat::soucin), ale i v balíku, který je aktuální ve chvíli, kdy je modul importován (v našem případě tedy většinou main). Vše, co je v poli @EXPORT, bude importováno do tabulky symbolů souboru, který tento modul zavolal.

Použijeme modul Mat, který jsme definovali v minulém dílu. Pomocí modulu Exporter mu vytvoříme rozhraní. Zde vidíme zdrojový kód nového modulu Mat.

package Mat;

use Exporter;
our @ISA = qw(Exporter);
our @EXPORT = qw(&soucet &soucin);

sub soucet {...};
sub soucin {...};
sub rozdil {...};
sub podil {...};
1;

Pole @ISA obsahuje název rodičovské třídy. Pro tuto chvíli to není tolik podstatné a zabývat se jím budeme až v souvislosti s dědičností. Na dalším řádku se přiřazují názvy identifikátorů soucet a soucin do pole @EXPORT. Tyto identifikátory budou v programu, kam je modul importován, viditelné jak v balíku Mat, tak i v balíku main.

To znamená, že po importu modulu Mat máme v programu k dispozici proměnné Mat::soucet, Mat::soucin, Mat::rozdil, Mat::podil a navíc i main::soucet a main::soucin, které bychom bez použití Exporteru neměli.

Zde je ukázka použití rozhraní našeho modulu.

use Mat;
print soucin(10, 8, 6, 3);
print Mat::soucin(10, 8, 6, 3);

Nicméně, jak jistě někoho mohlo zarazit, pole @EXPORT znečišťuje jmenný prostor pro samotný program. Tím se sami částečně zbavujeme výhod odděleného prostoru jmen. Proto, je-li to možné, je lepší dávat přednost poli @EXPORT_OK.

Pole @EXPORT_OK

Než začneme s výkladem této struktury, je třeba uvést, že všechny identifikátory uložené v poli @EXPORT mají automaticky také vlastnosti, které mají identifikátory uložené v @EXPORT_OK (což ale neznamená, že se do @EXPORT_OK automaticky ukládají).

@EXPORT_OK obsahuje identifikátory, které mohou (ale nemusí) být dostupné i z balíku, ve kterém je modul importován. Je totiž na autorovi programu, aby se rozhodl, které identifikátory chce mít importované do svého balíku (proto je vzhledem k autorovi programu používání pole @EXPORT_OK slušnější než @EXPORT).

Uživatel modulu (tedy autor programu) při importu pomocí use dá sám na vědomí, které identifikátory chce importovat. To se dělá přidáním seznamu požadovaných identifikátorů k příkazu use.

use Mat qw(&soucin);

Žádné jiné identifikátory než &soucin nebudou v daném balíku programu dostupné. Je-li &soucin v @EXPORT nebo @EXPORT_OK, bude se importovat &soucin a nic jiného. V okamžiku, kdy dáváme příkazu use tento parametr totiž jako vedlejším efektem zakazujeme import čehokoliv dalšího bez ohledu na obsah pole @EXPORT. Toto je pro uživatele modulu cesta, jak si snadno ohlídat svůj jmenný prostor.

S tím souvisí uvedení prázdného seznamu identifikátorů. Tímto říkáme příkazu use, že nechceme za žádných okolností cokoliv importovat.

use Mat ();

To, že nejsou některé proměnné nebo programy importovatelné ale vůbec neznamená, že se k nim nedá dostat! Není-li v modulu proměnná deklarovaná lokálně (pomocí my), vždy ji můžeme z programu, kam je načten modul, přečíst uvedením plně kvalifikovaného názvu.

Odtud plyne, že soukromá a veřejná data Perl nepodporuje. Jak už bylo řečeno, lze to obejít definicí lokálních proměnných. Jinou věcí jsou soukromé podprogramy. Tam je to složitější. Jedinou možností, jak je před uživatelem modulu zaručeně ukrýt, je vytvořeního lokální odkazu na anonymní podprogram. Nicméně vychovaný programátor by nezdokumentované vlastnosti modulů používat neměl.

Hash %EXPORT_TAGS

Pomocí %EXPORT_TAGS můžeme logicky třídit identifikátory. To je výhodné zejména u rozsáhlých modulů, které produkují spoustu identikátorů.

Nechť máme nějaký rozsáhlý modul Mat, ve kterém jsou definované podprogramy soucin, soucet, rozdil, podil, zaokrouhli_dolu, zaokrouhli_nahoru, zaokrouhli, sin, tan, cos, faktorial. Už na první pohled vidíme, že některé spolu souvisejí více, některé méně. První tematický celek tvoří funkce soucin, soucet, rozdil a podil; dalším jsou funkce zaokrouhli_dolu, zaokrouhli_nahoru, zaokrouhli; zbývají goniometrické funkce sin, tan, cos a nakonec ještě faktorial, který necháme nezařazený. Všechny tyto funkce dohromady tvoří další celek.

Klíčem prvku hashe %EXPORT_TAGS je vždy název skupiny a hodnotou odkaz na pole prvků, které do této skupiny patří.

%EXPORT_TAGS = (
    zakladni_operace => [qw(&soucin &soucet &rozdil &podil)],
    zaokrouhlovani => [qw(&zaokrouhli_nahoru &zaokrouhli_dolu &zaokrouhli)],
    goniometrie => [qw(&sin &tan &cos)]
);

Identifikátory v %EXPORT_TAGS musí být současně i v proměnné @EXPORT nebo @EXPORT_OK.

Implicitně je také nastavena skupina identifikátorů :DEFAULT, která obsahuje všechny identifikátory, které jsou zároveň v @EXPORT.

Ukažme si, jak by vypadalo užití modulu s uvedeným rozhraním. Kdybychom chtěli do vlastního programu importovat skupinu zakladni_operace, funkci faktorial a funkci sin, vypadala by struktura příkazu use takto.

use Mat qw(:zakladni_operace &faktorial &sin);

Názvy identifikátorů lze uvést i jako regulární výraz. Vložíme všechny, které obsahují řetězec ou.

use Mat qw(/ou/);

Předřazením vykřičníku můžeme jednotlivé prvky seznamu u příkazu use negovat.

Skalární proměnná $VERSION

Do $VERSION v modulu přiřadíme racionální číslo, které vyjadřuje číslo verze tohoto modulu.

$VERSION = 5.12;

Při použití modulu v samotném programu lze pak uvést, jaké minimální může být číslo verze. To se uvádí za název modulu v příkazu use. Taková možnost se hodí například v případech, kdy potřebujeme nějakou funkci, která v nižší verzi importovaného modulu nebyla ještě dostupná.

use Mat 7.0 qw(:zakladni_operace);

Požadujeme minimální verzi 7.0, což ale náš modul nesplňuje, protože ho máme ve verzi 5.12. V takovém případě program přeruší činnost a objeví se chybová hláška.

Mat version 7 required--this is only version 5.12 at mat.pl line 1.

Je třeba dát pozor na to, jak se čísla verzí porovnávají. Čísla verzí jsou ve skutečnosti racionálními čísly a tedy 5.10 je menší než 5.9! V takových případech musíme verze číslovat jinak. Například 5.09 a 5.10.

Překrytí standardních funkcí

Spíše jako zajímavost si uveďme, že je v modulu možné definovat již implementovanou funkci. Stačí k tomu vytvořit si modul s novou definicí této funkce. Jako ukázku se pokusíme upravit chování funkce chomp. Hodnotu bude přímo tisknout a navíc odstraní nejen znak nového řádku z konce řetězce, ale veškeré bílé znaky na začátku nebo konci řetězce.

Definujeme modul Chomp. Do pole @EXPORT uložíme jméno funkce, kterou chceme překrýt (chomp), aby se automaticky importovala do programu.

package Chomp;

use Exporter;
our @ISA = qw(Exporter);
our @EXPORT = qw(chomp);

sub chomp {
    my $retezec = shift;
    $retezec =~ s/^\s*(.*?)\s*$/$1/;
    print $retezec;
}
1;

Do programu už jen zavedeme vytvořený modul a použijeme funkci chomp.

use Chomp;
$x = "\n  abcd efa sd      \n";
chomp $x;

Řešení má háček. chomp změní chování jen v aktuálním balíku. To se dá řešit exportem funkce.

sub import {
    my($balik, @symboly) = @_;
    return unless @symboly; #pokud symboly nejsou, vyskočíme
    $balik->export("CORE::GLOBAL", @symboly);
}

Přestože je původní funkce překrytá, lze se k ní dostat. Stačí použít speciální balík CORE:: - místo funkce volat CORE::funkce. V našem případě bychom zavolali standartní chomp $x; jako CORE::chomp $x;.

Kdykoliv importujeme modul pomocí use, provede se speciální procedura import s parametry, jimiž jsou název modulu, a seznam importovaných symbolů. Používá se v něm často také funkce caller, která dává informace o volajícím souboru. Vrací jméno balíku, do kterého je modul importován, jméno souboru a číslo řádku s use.

Online verze článku: http://www.linuxsoft.cz/article.php?id_article=1281