Perl (34) - Formátování výstupu - formáty

Formát je dalším nástrojem pro tisk formátovaných dat.

23.5.2006 06:00 | Jiří Václavík | přečteno 15827×

Formáty slouží opět k vytváření výstupů podle šablony. Oproti printf se užívají zejména pro šablony větších rozsahů, kdy je užití formátů nejen přehlednější, ale i jednodušší.

Abychom mohli formáty používat, musíme ze všeho nejdříve definovat šablonu, kterou potom můžeme libovolněkrát použít.

Definice šablony

Šablona se definuje klíčovým slovem format. Jeho syntaxe obsahuje název formátu, uvozující rovnítko, masky, hodnoty a ukončující tečku.

format NAZEV =
formátovací_řetězec1
hodnoty1
formátovací_řetězec2
hodnoty2
...
.

Nezadáte-li název, implicitně se použije název cíle dat - v našem případě většinou STDOUT.

Formátovací řetězec se skládá z prvků, které začínají znakem @. Může obsahovat i text. Zde jsou znaky, které lze používat:

Znak formátovacího řetězceVýznam
@začíná položku hodnoty
^začíná položku postupně vkládané hodnoty
>zarovnání doprava
<zarovnání doleva
|zarovnání na střed
...zobrazí ..., pokud se nevešel celý řetězec
#zobrazování čísel, ale pokud je uveden jako 1. znak řádku, pak se bere jako začátek komentáře. Implicitně se zarovnává doprava
0zarovnání nulami zleva
.desetinná tečka
~nebudou vytištěny prázdné řádky
~~vypisuje text po řádcích
@*vypisuje libovolně dlouhý text
^*vypisuje libovolně dlouhý řádek textu

Abychom si lépe ujasnily význam těchto znaků, vyjádříme z nich několik konkrétních vzorů. Jak se můžete z tabulky přesvědčit, je jejich vytváření intuitivní.

Formátovací řetězecVýznam
@<<<<prvních 5 znaků (zavináč také zastupuje znak) zadaného textu, zarovnání doleva
@>>>>>>>>>hodnota zarovnaná doprava
@>>>>>>>>>...hodnota zarovnaná doprava, pokud se nevejde, končí třemi tečkami
@|||||||||centrovaná hodnota
@###.##desetinné číslo ve tvaru xxxx.xx, zleva případně doplněné mezerami
@0##.##desetinné číslo ve tvaru xxxx.xx, zleva případně doplněné nulami
@*libovolně dlouhý řetězec

Jako ukázku si napíšeme pro začátek jednoduchou šablonu. Bude tisknout prvních 20 znaků z dané proměnné. Text přitom bude vycentrován uvnitř hranatých závorek.

format =
[@|||||||||||||||||||]
$text
.

Aplikace šablony

Data zobrazíme funkcí write, které můžeme předat jako parametr ovladač, kam se budou data posílat. Ovladač je zde svázán se jménem šablony. Důsledkem toho je, že použijeme-li pro výstup funkci write, bude vytištěn záznam podle příslušného formátu.

Následujícím způsobem aplikujeme šablonu vytvořenou výše.

$text = "centrovaný text";
write;

format =
[@|||||||||||||||||||]
$text
.

Pokud používáme jiný formát než STDOUT a chceme tisknout na STDOUT, musíme ještě před tiskem nastavit proměnnou $~. V té je uchováván implicitně používaný formát.

$~ = "DATA";
$text = "centrovaný text";
write;

format DATA =
[@|||||||||||||||||||]
$text
.

Příklad užití

Pokusme se ještě o jeden příklad. Vytvoříme formátovaný kurzový lístek. Data, uložená v hashi, vypíšeme pomocí cyklu. Každou jeho iteraci bude volán příkaz write;.

my($mena, $cena);
my %kurzy = (
    "Austrálie AUD" => 17.283,
    "Čína CNY" => 2.808,
    "Dánsko DKK" => 3.8,
    "EMU EUR" => 28.335
);

foreach my $key (keys %kurzy){
    $mena = $key;
    $cena = $kurzy{$key};
    write;
}

format =
Měna: @<<<<<<<<<<<<<< Cena v korunách: @####.##
      $mena,                           $cena
.

Výstup se nám přesně podle šablony zformátuje. Nutno však poznamenat, že na takto jednoduchý příklad by stačila i funkce printf.

Rozdělení textu do více řádků

Výměnou @ za ^ lze dosáhnout rozdělení obsahu proměnné na více řádků s pevnou délkou. Zároveň jsou zachovávány slova, je-li to možné. Zvolme například 15 znaků jako délku řádku.

$text = "Nějaký text, který chceme rozdělit na více částí.";
write;

format =
[^||||||||||||||]
$text
.

To ještě není rozdělení, ale pouze odříznutí všeho, co je za 15. znakem.

$ perl format.pl
[ Nějaký text, ]
$

Nyní provedeme skutečné rozdělení.

$text = "Nějaký text, který chceme rozdělit na více částí.";
write;

format =
[^||||||||||||||]
$text
[^||||||||||||||]
$text
[^||||||||||||||]
$text
[^||||||||||||||]
$text
[^||||||||||||||]
$text
.

Text je úspěšně rozdělen.

$ perl format.pl
[ Nějaký text, ]
[ který chceme ]
[ rozdělit na ]
[ více částí. ]
[ ]
$

Sice jsme dosáhli cíle, nicméně za vysokou daň. Sami asi ze zdrojového kódu vidíte, že takto postupovat nelze. Celý formát je navržen absolutně nepružně. Tento problém však elegantně vyřešíme pomocí již zmíněné sekvence ~~.

$text = "Nějaký text, který chceme rozdělit na více částí.";
write;

format =
[^||||||||||||||]~~
$text
.

Nyní již není omezena délka textu, protože se automaticky vytvoří potřebný počet řádků.

Poznámka - Perl implicitně neláme slova. Pokud však příkazem

$: = "";

nastavíme, že lámat lze všude, dostaneme následující výstup.

$ perl format.pl
[Nějaký text, kt]
[erý chceme rozd]
[ělit na více čá]
[ stí. ]
$

Výpis řádků s odsazením

Sekvenci ~~ lze užít mimo předchozího i k dalším účelům. Níže uvedený kód vypisuje seznam, jehož položky jsou přehledně pod sebou.

$text = "1. položka\n2. položka\n3. položka\n4. položka\n";
write;

format =
Seznam: ^*
        $text
        ^* ~~
        $text
.

Nejprve je vypsán 1. řádek textu za řetězcem Seznam:, poté se vypíše o řádek níž další a protože je uvedeno ~~, bude se to opakovat, dokud bude nějaký řádek k dispozici.

Je nutné si uvědomit, že ^* ve vzoru zastupuje 1. položku (resp. řádek) a ^* ~~ postupně všechny ostatní položky.

Položky se nám tak srovnají pod sebe, což můžeme vidět na výstupu.

$ perl format.pl
Seznam: 1. položka
        2. položka
        3. položka
        4. položka
$

Zápis formátovaného textu do souboru

Při přesměrování výstupu do souboru ovladač souboru pojmenujeme stejně jako je název formátu. Parametrem write potom musí být název ovladače. Zapíšeme do souboru tabulku, obsahující 1., 2., 3., 4. a 5. mocniny čísel 0-20.

open FILE, ">soubor";

for ($x=0; $x<=20; $x++){
    write FILE; #totéž co select FILE; write;
}

close FILE;

format FILE =
@######## @######## @######## @######## @########
$x,       $x**2,    $x**3,    $x**4,    $x**5
.

Hlavičky

Dosud jsme produkovali šablony, které mají značnou nevýhodu. Nelze jim vložit hlavičky. To je u různých tabulek nebo sloupcových výčtů nezbytné. Ještě než se začne aplikovat šablona, potřebujeme aby se automaticky aplikovala šablona hlavičky.

Perl nabízí následující řešení. Máme formát TABULKA. Vytvoříme další formát s názvem TABULKA_TOP, který bude obsahovat právě formát hlavičky. Příkazem write; se nyní jednou provede hlavička a poté se vypisují už jen data. Platí, že je-li definován formát NÁZEVFORMÁTU_TOP, je aplikován jako hlavička formátu NÁZEVFORMÁTU.

Poslední příklad na zápis tabulky do souboru trochu rozšíříme. Přidáme do něj hlavičku tak, že vytvoříme formát FILE_TOP.

format FILE_TOP =
@>>>>>>>> @>>>>>>>> @>>>>>>>> @>>>>>>>> @>>>>>>>>
"x",       "x^2",     "x^3",     "x^4",     "x^5"
-------------------------------------------------
.

Patičky

Definice patiček je o něco složitější. Je nutné nastavit 2 speciální proměnné. Proměnná $= specifikuje po kolika vypsaných řádcích (do kterých se počítají i řádky hlavičky) bude pata vypisována. V proměnné $^L je pak samotný obsah patky.

Je-li tedy v proměnné $= hodnota 10, každých 10 řádků výstupu formátu se vypíše patka, poté znovu hlavička a dál pokračují data. Po vypsání dat je ale nutné ještě zvlášť vypsat hlavičku, aby na poslední straně nechyběla.

$= = 10;
$^L = "---------KONEC---------\n\n";

for ($x=0; $x<=50; $x++){
    write; #totéž co select FILE; write;
}
print $^L;

format =
Řádek: @<
       $x
.

format STDOUT_TOP =
----ZAČÁTEK STRANY----
.

Je zde jeden nedostatek. Pata na poslední straně může být klidně třeba v polovině stránky. My bychom ale chtěli každou patku přesně na konec strany (tedy na stejné místo jako na ostatních stranách). To obnáší vynechat nějaký proměnný počet řádků. A právě počet řádků, které zbývají do konce strany, je uložen v proměnné $-. Řádek print $^L; nahradíme za:

print "\n" x $- . $^L;

Stránkování

V proměnné $% je vždy uloženo aktuální číslo strany. Změníme hlavičku tak, aby ho obsahovala. Formát STDOUT_TOP bude vypadat takto:

format STDOUT_TOP =
---ZAČÁTEK STRANY @<--
                  $%
.

Příště začneme debugging.

Online verze článku: http://www.linuxsoft.cz/article.php?id_article=1224