Perl (28) - Rozsahy platnosti proměnných

Jak v Perlu vytvářet lokální a globální proměnné?

7.3.2006 06:00 | Jiří Václavík | přečteno 18950×

Definici proměnných lze provádět třemi funkcemi. V minulých dílech jsme používali pouze funkci my, aniž bychom hlouběji pátrali po jejích účincích. Mimo my existují s podobným významem další 2 funkce - local a our.

S definicemi proměnných souvisí to, že Perl umožňuje užívat pro různé datové typy proměnné stejného názvu. Podprogram &prog, skalární proměnná $prog, hash %prog, pole @prog, formát prog nebo ovladač prog. Všechno to jsou identifikátory se stejným názvem. Existují tzv. typegloby, které sdružují identifikátory se stejným názvem.

Lexikální platnost proměnné

Funkce my lexikálně deklaruje lokální proměnnou. Její rozsah platnosti je omezen jen na blok. To znamená, že je přístupná pouze zde a z jiného bloku není její hodnota žádným způsobem zjistitelná. Hodnota takové proměnné není dostupná ani z podprogramů volaných ze stejného bloku (jde však spíše o podstatu než o praktické využití takových podprogramů).

Proměnná pozbývá platnosti s ukončovací složenou závorkou aktuálního bloku. Stejně jako pro bloky za podmínkou nebo v podprogramu to platí i pro holé bloky. Důkazem toho je následující ukázka.

{
    my $p = 1;
}
print $p;

Vytisknuto není nic, protože platnost lokální proměnné $p je omezena jen na blok.

Plně kvalifikované jméno proměnné

Lokální proměnná pro daný blok vždy překryje globální proměnnou stejného názvu a datového typu. Přestože je proměnná překrytá, můžeme k ní přistupovat. Doteď jsme, aniž bychom si to uvědomovali, proměnné nepojmenovávali celými názvy, ale pouze jejich částmi. Plné jméno globální proměnné se skládá nejen z názvu, kterým jsme dosud vždy proměnné identifikovali, ale i z názvu balíčku, ve kterém se nachází.

Pokud příkazem package balíček neměníme, je implicitním balíčkem main. Z libovolného místa pomocí něj můžeme získat hodnotu proměnné $x, která je v tomto balíčku definována - a to zápisem $main::x. Proměnnou balíčku nelze deklarovat pomocí my, protože my deklaruje proměnné lexikálně. To znamená mimo jiné to, že taková proměnná pouze překrývá proměnnou globální. Pokud ve stejném bloku definujeme proměnnou balíčku a následně lexikální proměnnou se stejným názvem, vytvoříme tím 2 různé proměnné! K té lexikálně deklarované přistupujeme stejně jako dosud, ale chceme-li použít globální proměnnou stejného názvu, je třeba ji plně kvalifikovat.

Dynamická platnost proměnné

Další funkcí pro deklaraci proměnných je local. Syntaxe je shodná se syntaxí funkce my. Proměnné takto deklarované mají tzv. dynamicky vymezenou platnost. Při deklaraci funkcí local je případná hodnota proměnné stejného názvu jen odložena a nahrazena do konce bloku jinou hodnotou. Poté se opět vrátí na původní globální hodnotu. Takže i po deklaraci funkcí local jde o globální proměnnou! Jen je dočasně změněna její hodnota. Z tohoto důvodu je vidět i v podprogramech, volaných z bloku s deklarací.

local se užívá jen málo, ale přesto je pro některé úkoly účinným pomocníkem. Kupříkladu při práci s vestavěnými proměnnými. Potřebujeme na chvíli nějakou vestavěnou proměnnou změnit? To je úkol přesně na míru šitý pro funkci local.

{
    local $, = ", ";
    print @pole;
}

Vestavěná proměnná je do konce bloku nahrazena novou hodnotou. Dále se o nic nemusíme starat, protože za blokem se obsah vestavěné proměnné opět nahradí původní hodnotou.

Srovnání my a local

Stručně tedy shrňme rozdíl mezi my a local. local nedeklaruje žádnou novou proměnnou, pouze dočasně pozmění hodnotu globální proměnné stejného názvu. Oproti tomu my deklaruje skutečnou lokální proměnnou, která v daném bloku překrývá globální proměnnou.

To byla teorie. Následující příklad se dvěma podprogramy je typickou ukázkou činnosti zmiňovaných funkcí.

$my = 1;
$local = 1;
a();

sub a {
    local $local = 2;
    my $my = 2;
    b();
}

sub b {
    print "LOCAL:", $local, "\n";#vytiskne 2
    print "MY:", $my, "\n"; #vytiskne 1
}

Voláme podprogram &a. V něm je pomocí my vytvořena lokální proměnná $my a zároveň je pozměněna hodnota globální proměnné $local. Dále je v tomto podprogramu volán jiný podprogram &b, v němž jsou tisknuty proměnné $my a $local. Protože žádné lokální proměnné takových jmen neexistují, tisknou se globální proměnné. V případě my je vytisknuto 1, protože tato globální hodnota byla určena už na 1. řádku. V případě local se tiskne hodnota 2. To je také hodnota globální proměnné, která však byla v podprogramu &a dočasně pozměněna.

Stejně to funguje například s hashi. Nelze napsat

my $hash{"x"} = 1;

ale pouze překrýt prvek $hash{"x"} lze. Použijeme-li local, bude jen odložena globální hodnota prvku a dočasně nahrazena novou.

local $hash{"x"} = 1;

Definice globální proměnné

Funkce our deklaruje globální proměnné. A to úplně kdekoliv. Nezáleží na hloubce zanoření. Jedinou podmínkou je, že deklarace musí proběhnout před použitím proměnné. Proměnné deklarované pomocí our jsou obsaženy v balíku (jsou tedy skutečnými globálními proměnnými), čehož lze využít pro vytváření globálních proměnných v režimu strict.

{
    our $x = 1;
}
print $x;

Příklad tiskne 1, protože funkce our deklarovala globální proměnnou. Ta je globálně platná od okamžiku deklarace. Kdybychom místo our použili my, stala by se proměnná $x naopak lokální.

Zajímavostí je, že lze proměnnou deklarovat pomocí our i local zároveň. Vytváříme tak globální proměnnou, která však má hodnotu pouze v bloku.

{
    local our $p = 1;
    print "V BLOKU: $p\n";
}
print "MIMO BLOK: $main::p\n";

V příštím díle se zaměříme na práci se soubory.

Online verze článku: http://www.linuxsoft.cz/article.php?id_article=1118