Perl (26) - Podprogramy

Uživatelsky definované funkce jsou základem programování složitějších aplikací. Pojďme si je přiblížit.

9.2.2006 06:00 | Jiří Václavík | přečteno 25903×

Pomocí podprogramů lze program rozložit na kratší úseky, což pomáhá hned v několika aspektech. Některé části programu se až na pár detailů, jimiž jsou vstupní hodnoty, častěji opakují. Když je nutné tyto části nějak změnit (například kvůli vylepšení algoritmu nebo přidání dalších vlastností), musíme jich místo jediného řádku přepisovat třeba desítky. Toto tvrzení však neplatí, pokud použijeme podprogram.

Podprogram je uživatelsky definovanou funkcí. Vykonává nějaký úsek kódu na základě algoritmu, který je pro jeden podprogram vždy stejný, a vstupních hodnot, jenž tento algoritmus používá. Podprogram lze zapsat ve kterémkoliv místě programu, ale pro přehlednost bychom vždy měli zvolit nějaký systém. Vhodné je definovat podprogramy na konci nebo začátku programu, případně v modulu. Z hlavního programu (a samozřejmě i podprogramů) pak můžeme podprogramy volat. Jakmile je podprogram definován, práce s ním je stejná jako práce s předdefinovanými funkcemi, což jsou konec konců také podprogramy.

Neméně významnou výhodou podprogramů je zvýšení srozumitelnosti. Pokud zvolíme vhodné členění programu, lze poměrně rychle poznat, jak program funguje, aniž bychom museli číst kilobajty komentářů. Obzvláště u delších programů je tak mnohem snazší hledat chyby nebo je upravovat. Každý problém je rozložen na menší problémy a ty se řeší jednotlivě.

Další výhoda souvisí s tou prvně jmenovanou a spočívá v tom, že úseky programu, které mají být stejné, opravdu stejné jsou, neboť je píšeme pouze jednou.

Definice podprogramu

Definice pojmenovaného podprogramu vypadá následovně:

sub jméno {
    příkazy
}

Pomocí jména pak lze podprogram volat. Jak bude podrobněji rozebráno v příštím díle, lze do definice zahrnout i takzvaný prototyp. Pomocí něj si program může vyžádat počet, pořadí a typy argumentů.

sub jméno(prototyp) {
    příkazy
}

Volání podprogramu

Jménu podprogramu se předřazuje znak &. Seznam argumentů podprogramu se uvádí za jeho jménem v závorkách. Použijete-li závorky, uvedení & ve většině případů nebude nutné. Pokud není podprogram použit v souvislosti s odkazy nebo jako parametr některých funkcí, Perl sám rozezná, že jde o podprogram.

&prumer(2, 7);
prumer(2, 7);

Použití

Velice jednoduchý podprogram může vypadat takto:

$jmeno = "uzivatel";
pozdrav();

$jmeno = "root";
pozdrav();

sub pozdrav {
    print "Podprogram: Ahoj $jmeno, já jsem podprogram\n";
}

Nutno dodat, že tento podprogram nemá vůbec dobré vychování, neboť používá globální proměnné. Přijatelným řešením tohoto nedostatku bude předání argumentů podprogramu, jakmile se to naučíme.

Příklad by fungoval stejně i kdybychom nahradili řádek

pozdrav();

za

&pozdrav;

Argumenty a lokální proměnné

Jak již bylo napsáno pod posledním příkladem, použití globálních proměnných podprogramem je více než nešikovné. Kdyby všechny proměnné ve všech podprogramech sdílely tentýž prostor jmen, brzy bychom se zamotali. Proto je mnohem lepší předat podprogramu hodnotu jako argument. Ten v podprogramu uložíme do proměnné, která bude platná jen v rámci tohoto podprogramu (tedy bloku). Potom se uvnitř podprogramu vůbec nemusíme starat o jména globálních proměnných. Obecně platí, že čím víc je proměnná lokální, tím lépe.

Jak již víme, lokální proměnná se definuje pomocí funkce my. Funkcí podobných s my je více, ale zatím je pro jednoduchost zamlčím a někdy v blízké době si rozsahy platnosti rozebereme ve zvláštním díle.

Parametrem funkce je buď proměnná nebo seznam proměnných v kulatých závorkách. Než se pustíme do argumentů, uveďme si ještě příklad pro lepší pochopení funkce my.

$x = 7;
a();
b();
print "g: $x\n"; #tiskne 7 - lokální proměnná v &b byla platná jen pro
                 #daný blok. Po jeho ukončení má x opět globální hodnotu


sub a {
    print "b: $x\n"; #tiskne hodnotu globální proměnné x - tedy 7
}

sub b {
    my $x = 15;
    print "a: $x\n"; #vytiskne 15 - lokální proměnná přebíjí globální
}

Nyní už k věci. V podprogramu je seznam předaných argumentů uložen ve speciálním poli @_. Na začátku podprogramu se obvykle vytváří lokální proměnné, které z tohoto pole hodnoty přebírají. Pokud nejde o vyloženě triviální podprogram, není zrovna přehledné uvnitř něj používat proměnné $_[0], $_[1] a jim podobné.

Nyní, když známe teorii, pojďme si ukázat praxi. Definujeme podprogram tiskni_prumer, který přebírá jako argumenty 3 čísla a vypisuje jejich aritmetický průměr.

tiskni_prumer(6, 9, 33); #voláme funkci tiskni_prumer
                         #se třemi argumenty 6, 9, 33


sub tiskni_prumer {
    my($a, $b, $c) = @_;
    print (($a + $b + $c) / 3);
}

Do pole @_ jsou v našem případě uloženy hodnoty 6, 9 a 33. Ty jsme na 1. řádku podprogramu přiřadili do lokálních proměnných $a, $b a $c.

Další často užívaná možnost, jak získat hodnoty z @_ vede přes funkci shift. shift maže první prvek pole a jeho hodnota je výsledkem vyhodnocování.

print tiskni_prumer(6, 9, 33);

sub tiskni_prumer {
    my $a = shift @_;
    my $b = shift @_;
    my $c = shift @_;
    print (($a + $b + $c) / 3);
}

Pokud podprogram voláte bez uvedení seznamu (ať už třeba prázdného), je funkci automaticky předáno pole @_. To demonstruje následující příklad.

@_ = (1, 2, 3);
&tisk;

sub tisk {
    print @_;
}

Též můžete zkusit místo &tisk volat &tisk(). V takovém případě se @_ nepředává.

Předáváte-li podprogramu 2 pole, slijí se do jednoho. Toto lze řešit pomocí odkazů, které prozatím necháme stranou. Je to též možné pomocí globálních názvů, ale jak již bylo několikrát řečeno, není vhodné, aby funkce jakkoliv zasahovala do svého okolí.

Návratová hodnota podprogramu

Co když nechceme, aby podprogram výsledky vypisoval, ale chceme je přiřadit do nějaké proměnné a následně je použít? Od toho je zde návratová hodnota - tedy hodnota, kterou bude vracet volání podprogramu při vyhodnocování. Právě díky návratové hodnotě tak můžeme podprogram volat na pravé straně od operátoru přiřazení.

$prumer = prumer(6, 9, 33);

sub prumer {
    my($a, $b, $c) = @_;
    my $prumer = ($a + $b + $c) / 3;
}

Jako návratová hodnota je automaticky považována poslední hodnota v podprogramu - v našem případě jí byla proměnná $prumer.

Chcete-li návratovou hodnotu výslovně uvést, což doporučuji, použijte klíčové slovo return. Jeho parametrem je návratová hodnota.

$prumer = prumer(6, 9, 33);

sub prumer {
    my($a, $b, $c) = @_;
    return ($a + $b + $c) / 3;
}

Program, který bude vracet průměr 3 hodnot asi nebude mít příliš velký význam. Posuneme se proto dále. Daleko větší uplatnění jistě má funkce, která počítá aritmetický průměr nezávisle na počtu argumentů.

sub spocitej_prumer {
    my $soucet = 0;
    $soucet += $_ for (@_);
    return ($soucet / scalar @_);
}

Deklarace

Jak už bylo řečeno, podprogram může být definován kdekoliv v programu. Pokud ale voláte podprogram dříve než ho definujete a zároveň používáte céčkovský styl volání (bez ampérsandu), musíte argumenty uzavřít do závorek. Spíše pro zajímavost uvádím, že pokud ještě před voláním podprogram deklarujete, lze závorky vynechat.

sub prumer; #deklarace

prumer 1, 2, 6;

sub prumer {
    my ($a, $b, $c) = @_;
    print (($a + $b + $c) / 3);
}

Konstanty

Konstanta je speciální typ funkce, která neočekává žádný argument, ale pouze vrací nějakou hodnotu. Jelikož má takový podprogram při všech voláních stejné podmínky, vrací konstantní hodnotu. To, že odmítáme jakýkoliv argument, dáme na vědomí uvedením prázdného prototypu - ten zakazuje veškeré argumenty.

sub PI() { return 3.141592654 }

sub obsah_kruhu ($) {
    my($r) = @_;
    return PI*$r**2;
}

print obsah_kruhu(2);

Právě jsme poznali první prototyp. Příště si v tomto směru znalosti rozšíříme, neboť celý díl se bude věnovat právě jim.

Online verze článku: http://www.linuxsoft.cz/article.php?id_article=1092