LINUXSOFT.cz Přeskoč levou lištu
Uživatel: Heslo:  
   CZUKPL

> Perl (145) - POE - aplikace typu klient-server

Perl Zvyšováním abstrakce lze z procesů a nízkoúrovňových událostí postupně budovat stále větší a větší celky. Na CPANu máme řadu modulů, které fungují například jako socket servery.

1.11.2011 00:00 | Jiří Václavík | Články autora | přečteno 3545×

Na základě POE lze vytvářet i aplikace pro meziprocesovou komunikaci. Typicky slouží k vytváření klientů a serverů.

Existuje velké množství modulů, které začínají na POE::. Ty obsahují různé nástroje, které nám usnadní vytváření většiny POE aplikací. Nejprve se tedy stručně podívejme, co za nástroje nám vlastně POE:: moduly nabízejí.

  • Komponenty (POE::Component::) - komponenta je proces, který spravuje jiné procesy, může jít například o předpřipravený server
  • Wheels (POE::Wheel::) - základní algoritmy, které pomáhají s praktickými úkoly napříč různými servery; například vytvoření spojení se serverem
  • Drivery (POE::Driver::) - implementace IO vrstvy
  • Filtry (POE::Filter::) - konvertují nějaká data z jednoho formátu do jiného

Zajímat nás budou hlavně moduly typu Wheel a Component. Za chvíli se s nimi setkáme a uvidíme více.

Příklad - server jako kalkulačka

Budeme si demonstrovat základní postup při používání různých POE:: modulů.

Zkusíme si napsat jednoduchý server a klient. Server bude zpracovávat dotazy na výpočet a posílat je zpět klientům. Na zpracování můžeme použít například nějaký kalkulátor typu bc nebo dc.

Server

Především použijeme již připravený modul POE::Component::Server::TCP. To nám výrazně usnadní práci a výsledný zdrojový kód několikanásobně zkrátí. Abychom si demonstrovali také nějaký POE::Wheel modul, použijeme POE::Wheel::Run, který nám bude externě spouštět úlohy v kalkulátoru.

Používáme-li nějaké doplňkové moduly, můžeme je uvést bez POE:: jako parametr use POE. Jinak řečeno, pokud využijeme POE::Component::Server::TCP, můžeme POE zavést tímto příkazem.

use POE qw(Component::Server::TCP);

Nadále však bude fungovat i několikanásobné volání use, kterému zde budeme dávat přednost.

Pak již bude základní kostra programu skoro stejná jako u našich příkladů z minulého dílu. Jediným drobným rozdílem bude to, že místo POE::Session budeme vytvářet instanci POE::Component::Server::TCP, která se o vytvoření POE::Session postará sama.

#!/usr/bin/perl
use warnings;
use strict;
use POE;
use POE::Component::Server::TCP;
use POE::Wheel::Run;

POE::Component::Server::TCP->new(
    # tady bude všechno důležité
);

POE::Kernel->run;

Nyní tedy stačí napsat vnitřnosti serveru, to jest parametry ve tvaru klíč - hodnota. Ostatně, jak uvidíme i dále, vše v POE jsou vlastně parametry tvaru klíč - hodnota. Jedním z klíčů bude InlineStates, se kterým jsme se setkali již minule. Ten bude uchovávat některé ovladače.

    InlineStates => {
        # ovladače
    }

Dalším klíčem bude Port, kde uvedeme, na kterém portu budeme očekávat klienty.

    Port  => 22224,

Pak ještě ošetříme dvě speciální události, které mají definovaný vlastní klíč (o to se stará POE::Component::Server::TCP) - ClientConnected, ClientInput. To jsou události, které nastanou, jakmile se klient připojí, odpojí resp. pošle dotaz. Samozřejmě, že takových událostí existuje celá řada. Jejich vyčerpávající přehled je uveden v dokumentaci.

Jakmile se uživatel připojí, slušelo by se poslat mu uvítací zprávu. Vyvoláme tedy událost vitejte, kterou budeme muset později dopsat do InlineStates.

    ClientConnected => sub {
        $_[KERNEL]->yield("vitejte");
    }

Nejkomplikovanější ovladač bude ClientInput. Všimněme si, že jako parametr označený ARG0 dostaneme vstup od klienta, který můžeme dále zpracovávat.

Nás nyní bude zajímat hlavně to, jak použijeme avizované POE::Wheel::Run, které se má postarat o zavolání kakulátoru. Předně si ujasněme, jaký shellový příkaz budeme vlastně volat. Zvolme si například kalkulátor bc, který příkazy zpracovává takto.

$ echo '2+3' | bc -l

Zavoláme tedy POE::Wheel::Run a předáme mu šablonu pro tento příkaz pod klíčem Program. Ještě musíme předat další dva parametry s hodnotami - StdoutEvent (parametrem bude jméno ovladače, který bude volán, jakmile náš příkaz vyprodukuje výstup na STDOUT) a CloseEvent (to je zas znamení, že je výstup dat z volaného příkazu u konce).

Takto tedy může vypadat ošetření v ovladači ClientInput.

    ClientInput => sub {
        my $data    = $_[HEAP];
        my $vypocet = $_[ARG0];

        if ($data->{cmd} or $vypocet =~ m/\\'/) {
            return;
        }

        $data->{cmd} = POE::Wheel::Run->new(
            Program      => "echo '$vypocet' | bc -l",
            StdoutEvent  => "odpoved",
            CloseEvent   => "konec",
        );
    },

Nyní nám zbývá dopsat ovladače vitejte, odpoved a konec. Poznamenejme nejprve, že data klientovi odešleme metodou put. První dva budou prostým odesláním dat klientovi. Ten třetí uklidí nepořádek, který v $_[HEAP]->{cmd} nechal POE::Wheel::Run.

    InlineStates => {
        odpoved => sub {
            my $odpoved = $_[ARG0];
            $_[HEAP]->{client}->put($_[ARG0]);
        },
        konec => sub {
            delete $_[HEAP]->{cmd};
        },
        vitejte => sub {
            $_[HEAP]->{client}->put("Vítejte na POE serveru");
        },
    },

Dodejme, že u tohoto serveru uživatel musí zadávat korektní dotazy, jinak se odpovědi nedočká.

Připojení na server

K serveru se samozřejmě můžeme připojit běžnými nástroji jako například telnet. Spustťme tedy server a na nějaké jiné konzoli spustíme telnetového klienta.

$ telnet localhost 22224
Trying ::1...
telnet: connect to address ::1: Connection refused
Trying 127.0.0.1...
Connected to localhost.
Escape character is '^]'.
Vitejte na POE serveru
5*7
35

Klient

Ačkoliv se můžeme připojit telnetem nebo jinými běžnými klienty, napíšeme si také svého vlastního. Ten bude opět používat POE.

Klient bude fungovat na základě podobné logiky jako server. Pro usnadnění použijeme komponentu POE::Component::Client::TCP. Kostra aplikace opět vypadá následovně. Rovnou přidáme zřejmé parametry pro port a hostitele.

#!/usr/bin/perl
use warnings;
use strict;

use POE;
use POE::Component::Client::TCP;

POE::Component::Client::TCP->new(
    RemoteAddress => "localhost",
    RemotePort => 22224,
    # tady bude náš klient
);

POE::Kernel->run();

POE::Component::Client::TCP opět sám generuje řadu událostí, na které je snadné reagovat. Například událost Connected se objeví, jakmile jsme připojeni k serveru.

    Connected => sub {
        print "Jsme připojeni\n";
    }

Nás však bude zajímat především událost ServerInput, ke které dojde, jakmile nám server pošle data. Data opět máme dostupná pod proměnnou $_[ARG0]. Data tedy přijmeme, zobrazíme (poprvé to bude uvítací zpráva, následně pak výsledky na naše dotazy) a poté můžeme provádět dotazy. Na to si vytvoříme vlastní ovladač proved.

    ServerInput => sub {
        my $odpoved = $_[ARG0];
        print "Výsledek: $odpoved\n";
        $_[KERNEL]->yield("proved");
    },

Uvnitř proved se uživatele nejprve zeptáme na příkaz a poté ho pošleme serveru. Ještě můžeme například ošetřit, zda uživatel náhodou nechce program ukončit.

    InlineStates => {
        proved => sub {
            print "příkaz> ";
            my $cmd = <STDIN>;
            if($cmd =~ m/\A(?:quit|q|exit|konec)/){
                $_[KERNEL]->yield("shutdown");
                return;
            }
            $_[HEAP]{server}->put($cmd);
        }
    }

Závěr

Nyní tedy máme jak server tak klienta. Ke stažení jsou zde: server.pl, klient.pl. Můžeme si zkusit spustit server a jednoho nebo několik klientů. S klientem lze pracovat například takto.

$ perl klient.pl
Jsme připojeni
Výsledek: Vitejte na POE serveru
příkaz> scale=50;4*a(1)
Výsledek: 3.14159265358979323846264338327950288419716939937508
příkaz> 2+3
Výsledek: 5
příkaz>

Verze pro tisk

pridej.cz

 

DISKUZE

Nejsou žádné diskuzní příspěvky u dané položky.



Příspívat do diskuze mohou pouze registrovaní uživatelé.
> Vyhledávání software
> Vyhledávání článků

23.9.2014 6:55 /MaReK Olšavský
Spolešnosti InfiniDB došly peníze, ale vyvinutý software se neztratí, protože zdrojové kódy jsou umístěny na GitHubu. Prozatimní informace mluví o konci vývoje, ale je možné, že zdrojové kódy budou dále vyvíjeny komunitou.
Přidat komentář

23.9.2014 6:54 /MaReK Olšavský
Spektrum programovacích jazyků asi připadá některým programátorům velmi úzké. Nabídku chce rozšířit skupina programátorů „zjednodušeným C“, které připravuje v projektu CLike, využívajícím backend LLVM. Další příspěvek vymýšlí herní vývojář Jon Blow, jehož cílem je programovací jazyk pro hry (herní vývojáře).
Přidat komentář

23.9.2014 6:54 /MaReK Olšavský
Indie je zajímavá z hlediska nástupu nových mobilních platforem. Nedlouho po zahájení prodeje levného přístroje s Firefox OS se na indický trh chystá Samsung s Tizenem. Podíl Samsungu je zatím v Indii velmi malý.
Přidat komentář

22.9.2014 7:29 /MaReK Olšavský
Bojkot, ze strany některých vývojářů, systemd přinesl ovoce v podobě jednoduché inicializační služby uselessd, která nemá zbytečné služby. Zatím je projekt na začátku, ale možná bude systemd jen krátkou kapitolkou v distribucích GNU/Linuxu.
Přidat komentář

19.9.2014 7:29 /MaReK Olšavský
Efektové pedály zná asi lecjaký hudebník, zejména hraje-li na elektrickou kytaru. Nový pohled na „efektové krabičky s pedály“ nabízí projekt MOD Duo s Arduinem, jehož autoři shání finance na Kickstarteru, který má nabídnout přibližně 100 efektů.
Komentářů: 1

19.9.2014 7:29 /MaReK Olšavský
Larry Ellison odstoupil z pozice CEO a zůstává jen předsedou správní rady Oracle. V čele Oracle stál od založení (1977), dnes je společnost známá jako tvůrce jedné z nejlepších databází a portfolio zahrnuje i MySQL, nebo Javu, jež získal koupí SUN Microsystems.
Komentářů: 1

19.9.2014 7:29 /MaReK Olšavský
Pokud vás láká Arch Linux, ale od jeho instalace odrazuje zdlouhavá práce, použijte Evo/Lution, který usnadní instalaci Archu, až do míry blízké Ubuntu/Mint Linuxu.
Komentářů: 2

19.9.2014 7:29 /MaReK Olšavský
Pro Ericsson končí další éra s koncem divize modemů, který mimo jiné přináší zrušení přibližně 1 000 pracovních míst. Výrobu modemů údajně přebírá STMicroelectronics.
Přidat komentář

   Více ...   Přidat zprávičku

> Poslední diskuze

22.9.2014 8:35 / Aleš Hakl
Re: To je hlod

22.9.2014 6:55 / MaReK Olšavský
Re: Ano, ale

19.9.2014 23:28 / Petr Ježek
výročí

19.9.2014 23:27 / Petr Ježek
pouze pro velké a chtivé

19.9.2014 23:22 / Petr Ježek
Ano, ale

Více ...

ISSN 1801-3805 | Provozovatel: Pavel Kysilka, IČ: 72868490 (2003-2014) | mail at linuxsoft dot cz | Design: www.megadesign.cz | Textová verze | zákony online