LINUXSOFT.cz Přeskoč levou lištu
Uživatel: Heslo:  
   CZUKPL

> Perl (49) - Tabulky symbolů a typegloby

Perl Kde jsou uložena jména proměnných? Co to jsou typegloby a k čemu jsou dobré?

2.1.2007 10:00 | Jiří Václavík | Články autora | přečteno 12592×

Tabulka symbolů

O tabulce symbolů již jsme se letmo zmiňovali. V ní jsou uloženy jména proměnných, ovladače, formáty, podprogramy a odkazy na ně. Takovou tabulku symbolů má každý balík.

Mimo tabulek symbolů existují ještě lexikální prostory, které mají trochu odlišnou funkci. Tam patří lexikálně vymezené proměnné. Lexikálně (tedy pomocí my) lze deklarovat pouze proměnné; nikoliv už ovladače, formáty nebo podprogramy. Lexikální prostor se vztahuje k aktuálnímu bloku. (Z tohoto důvodu lze v jednom bloku deklarovat 2 proměnné zdánlivě stejného jména - jedna z nich patří do tabulky symbolů, druhá do lexikálního prostoru aktuálního bloku.)

Podívejme se však na strukturu tabulky symbolů. V Perlu lze pro různé datové typy použít stejné identifikátory ($a, @a, &a atd.). Všechny identifikátory jsou uloženy ve speciálním hashi. Protože nemohou být klíče v hashi duplicitní, nemohou tam vedle sebe existovat dva stejné identifikátory, lišící se jen datovým typem. Z tohoto důvodu jsou v hashi jako hodnoty prvků takzvané typegloby.

Typeglob seskupuje stejné identifikátory různých datových typů a díky němu tak může být v tabulce symbolů pro proměnné @p, %p apod. vytvořen jediný prvek.

Tabulka symbolů je tedy uložena v hashi. Ten je v každém balíku dostupný pod jménem %jméno_balíku::. Konkrétně - pro balík main existuje tabulka symbolů v hashi %main::. Protože je balík main implicitní, lze použít i zkrácený zápis %::. Vypišme si jako ukázku tabulku symbolů balíku main.

foreach (sort keys %::){
    print $_, "=", $::{$_}, "\n";
}

Zkusme nyní ještě voláním tohoto kódu přidat nějaký nový symbol tím, že v programu použijeme novou proměnnou. Připíšeme například tento řádek.

$zzz;

V hashi se nám objevil nový prvek. Na výstupu vidíme následující řádek navíc.

zzz=*main::zzz

Takový tvar mají všechny vytisknuté řádky. Mění se jen jméno typeglobu, tedy v našem případě oba řetězce zzz.

Takto můžeme přidávat další jména. Nejen skaláry, ale i pole, hashe atd. Pro každý nový identifikátor se přidá nový řádek. To platí do doby, než přidáme identifikátor stejného jména, které v tabulce již je, neboť, jak bylo uvedeno, typeglob reprezentuje všechny datové typy dohromady.

Vlastnosti typeglobů

Zápis typeglobu vždy začíná znakem *. Již víme, že typeglob zastupuje jakýkoliv datový typ. Zde je pro shrnutí jejich seznam.

  • skalární proměnnou $main::zzz
  • pole @main::zzz
  • hash %main::zzz
  • podprogram &main::zzz
  • formát main::zzz
  • ovladač main::zzz

Jak se za chvíli přesvědčíme, dá se s typegloby pracovat podobně jako s jinými identifikátory a můžeme je často zaměňovat.

Důležitou skutečností je, že typegloby nelze deklarovat pomocí my. Pomocí my se deklarují pouze skaláry, pole a hashe. Lexikální prostory nic jiného obsahovat nemohou.

Neméně důležité je i to, že do typeglobů lze přiřazovat odkazy. Z toho budeme dále často vycházet.

Typegloby je možné předávat jako parametr podprogramům. Uvnitř podprogramu nelze z výše zmíněného důvodu použít k lokalizaci funkci my. Je nutné typeglobu vytvořit dočasný alias pomocí local. Příklad tohoto jevu je uveden níže.

Přiřazení

Přířazení typeglobu umožňuje hromadné kopírování odkazů datových typů stejného identifikátoru. Po přiřazení typeglobu do typeglobu mohou být data zpřístupněna i novou sadou identikátorů. Zde je krátká ukázka.

$zzz = "typeglob";
@zzz = ("a", "b", "c");

*zaloha = *zzz;
print $zaloha, "\n";
print @zaloha, "\n";

Proměnné @zaloha i @zzz nyní ukazují na stejnou hodnotu. To znamená, že když změníme jednu z těchto proměnných, obě budou ukazovat na změněnou hodnotu.

Další možností přiřazení pouze určitého datového typu. Chceme-li přiřadit odkaz na skalár a zároveň také aby se nepřiřadil odkaz na pole, napíšeme toto.

$x = 1;
@x = (2, 3);

*y = \$x;

print $y;#tiskne 1
print @y;#nic se netiskne - @y neexistuje!

Použití typeglobů

Nyní se podíváme na několik příkladů, kde se dají typegloby použít.

Pojmenování anonymnymních dat

Podívejme se na tento bezejmenný podprogram.

$sub = sub {
    print "Ja jsem podprogram\n";
};

Pokud z nějakého důvodu nechceme volat podprogram příkazem

&$sub();

lze ho přes typegloby pojmenovat. Stačí přiřadit proměnnou $sub do nějakého typeglobu.

*podprogram = $sub;

Odteď lze použít i toto volání.

&podprogram();

Naprosto stejně to funguje i pro jiné datové typy. Uveďme si jen ukázku s poli.

$r_pole = [1, 2, 3, 4, 5];  #vytvoření anonymního pole
*pojmenovane_pole = $r_pole;#pojmenování anonymního pole
print @pojmenovane_pole;    #už lze volat vlastním jménem

Šablony funkcí

Pomocí typeglobů ve spolupráci se symbolickými odkazy lze v cyklu deklarovat libovolné množství podprogramů s různými jmény, která máme uloženy v poli. Protože jsou k tomu ale potřeba symbolické odkazy, musíme vypnout režim strict "refs".

@jmena = qw(f g h);
foreach my $funkce (@jmena) {
    no strict 'refs';
    *$funkce = sub {print "Volany podprogram: $funkce\nPredane parametry: @_\n\n"};
}

Nyní máme vytvořené podprogramy f, g, h.

f(10, 20);
g();
h(1, 2, 3);

Vytvoření aliasu pro identifikátor

Představme si, že potřebujeme vytvořit 2 stejné podprogramy různého jména. Máme několik možností. Jednou z nich je prosté přiřazení typeglobu.

sub podprogram {
    print "@_\n";
}

*tiskni_argumenty = *podprogram;
&tiskni_argumenty(7, "X");

Tvoření odkazů podle speciální syntaxe

Pomocí syntaxe *identifikátor{DATOVÝ_TYP} lze získávat odkazy na příslušný datový typ.

@pole = (2, 3, 4);
$r_pole = *pole{ARRAY};
print @$r_pole;

Datový typ může být jedním z těchto řetězců.

  • SCALAR
  • ARRAY
  • HASH
  • CODE
  • IO
  • GLOB

Tímto způsobem můžeme předávat odkazy na ovladače podprogramům, což by si jinak člověk jen těžko představil.

open DATA, "ovladac.pl";

tiskni_z_ovladace(*DATA{IO});

sub tiskni_z_ovladace {
    my $fh = shift;
    print <$fh>;
}

Ještě jednou předávání ovladačů podprogramům

Pokud se vám právě uvedená metoda nezamlouvá, můžete místo ovladače předát rovnou typeglob, což je asi logičtější metoda. Jen je třeba pamatovat, že typegloby nelze vymezovat lexikálně.

open ZDROJ, "data" or die;

&tiskni_z_ovladace(*ZDROJ);

sub tiskni_z_ovladace {
    local(*DATA) = @_;
    print <DATA>;
}

Odkazy na ovladače

Ovladače jsou specifický datový typ. Nelze je mezi sebou přiřazovat a ani lokalizovat pomocí my nebo local.

Tato omezení lze obejít pomocí typeglobů.

Pokud máme ovladač ZDROJ a chceme ho přiřadit do ovladače Z, opět to uděláme přes typegloby (možná si ještě vzpomenete, že kdysi jsme si kopírování ovladačů již ukazovali; umí to funkce open). Napíšeme do programu toto.

open ZDROJ, "data" or die;
*Z = *ZDROJ;
print <Z>;

Podobně, chceme-li ovladač lokalizovat. Použijeme typeglob.

local *ZDROJ;

Ovladače mohou být i řetězci. Možné je toto.

$fh = *ZDROJ;
print <$fh>;

Přesměrování výstupu

Vypisuje-li nějaký program data na obrazovku a my je chceme přesměrovat do souboru, přiřadíme do *STDOUT jiný typeglob.

open CIL, ">vystup";
*STDOUT = *CIL;
print "cokoliv";

Verze pro tisk

pridej.cz

 

DISKUZE

rada otazek ... 2.1.2007 15:23 Johann von Nepomuk
  L Re: rada otazek ... 2.1.2007 16:41 Jiří Václavík
    L Re: rada otazek ... 2.1.2007 19:12 Johann von Nepomuk
      L Re: rada otazek ... 3.1.2007 21:08 Jiří Václavík




Příspívat do diskuze mohou pouze registrovaní uživatelé.
> Vyhledávání software
> Vyhledávání článků

14.5.2018 7:28 /František Kučera

Květnový pražský sraz spolku OpenAlt se koná již tento čtvrtek – 17. 5. 2018 od 18:00 v Kavárně Ideál (Sázavská 30, Praha), kde máme rezervovaný salonek. Tentokrát na téma: Audio – zvuk v GNU/Linuxu.


Přidat komentář

7.5.2018 16:20 /František Kučera
Na stránkách spolku OpenAlt vyšla fotoreportáž Pražské srazy 2017 dokumentující srazy za uplynulý rok. Květnový pražský sraz na téma audio se bude konat 17. 5. 2018 (místo a čas ještě upřesníme).
Přidat komentář

17.4.2018 0:46 /František Kučera
Dubnový pražský sraz spolku OpenAlt se koná již tento čtvrtek – 19. 4. 2018 od 18:00 v Kavárně Ideál (Sázavská 30, Praha), kde máme rezervovaný salonek. Tématem tohoto srazu bude OpenStreetMap (OSM) aneb svobodné mapy.
Přidat komentář

16.3.2018 22:01 /František Kučera
Kulatý OpenAlt sraz v Praze oslavíme klasicky: u limonády a piva! Přijďte si posedět, dát si dobré jídlo a vybrat z mnoha piv do restaurace Kulový blesk, který najdete v centru Prahy nedaleko metra I. P. Pavlova na adrese Sokolská 13, Praha 2. Sraz se koná ve čtvrtek 22. března a začínáme v 18:00. Heslo: OpenAlt. Vezměte s sebou svoje hračky! Uvítáme, když si s sebou na sraz vezmete svoje oblíbené hračky. Jestli máte nějaký drobný projekt postavený na Arduinu, nějakou zajímavou elektronickou součástku, či třeba i pěkný úlovek z crowdfundingové akce, neváhejte. Oslníte ostatní a o zábavu bude postaráno.
Přidat komentář

13.2.2018 0:41 /František Kučera
Únorový pražský sraz OpenAltu se koná 15. 2. 2018 a tentokrát se vydáme na návštěvu do jednoho pražského datacentra. Sejdeme se v 17:50 v severovýchodní části nástupiště tramvajové zastávky Koh-I-Noor. Po exkurzi se přesuneme do restaurace U Pštrosa (Moskevská 49), kde probereme tradiční témata (svobodný software a hardware, DIY, CNC, SDR, 3D tisk…) a tentokrát bude k vidění i IoT brána od The Things Network.
Přidat komentář

11.2.2018 23:11 /Petr Ježek
Hledáte lehký a rychlý prolížeč PDF souborů? Pokud vás již omrzelo čekat na načítání stránek či jiné nešvary, zkuste xreader.
Přidat komentář

11.2.2018 20:35 /Redakce Linuxsoft.cz
Třetí ročník odborné IT konference na téma Cloud computing v praxi proběhne ve čtvrtek 1. března 2018 v konferenčním centru Vavruška, v paláci Charitas, Karlovo náměstí 5, Praha 2 (u metra Karlovo náměstí) od 9:00 hod. dopoledne do cca 16 hod. odpoledne. Konference o trendech v oblasti cloud computingu nabídne i informace o konkrétních možnostech využívání cloudů a řešení vybraných otázek souvisejících s provozem IT infrastruktury.
Přidat komentář

15.1.2018 0:51 /František Kučera
První letošní pražský sraz se koná již tento čtvrtek 18. ledna od 18:00 v Radegastovně Perón (Stroupežnického 20, Praha 5). Vítáni jsou všichni příznivci svobodného softwaru a hardwaru, ESP32, DIY, CNC, SDR nebo dobrého piva. Prvních deset účastníků srazu obdrží samolepku There Is No Cloud… just other people's computers. od Free Software Foundation.
Přidat komentář

   Více ...   Přidat zprávičku

> Poslední diskuze

20.2.2018 18:48 / Ivan Majer
portal

20.2.2018 15:57 / Jan Havel
Jak využíváte služby cloudu v podnikání?

16.1.2018 1:08 / Ivan Pittner
verejna ip od o2 ubuntu

15.1.2018 17:26 / Mira Harvalik
Re: Jak udělat HTML/Javascript swiping gallery do mobilu?

30.12.2017 20:16 / Michal Knoll
odmocnina

Více ...

ISSN 1801-3805 | Provozovatel: Pavel Kysilka, IČ: 72868490 (2003-2018) | mail at linuxsoft dot cz | Design: www.megadesign.cz | Textová verze